GUIA DE TRABAJO PARA HOY (01122021) - NOVENO APLICACIÓN DE ALGORITMOS EMPLEANDO Pseint

 Diciembre 1 de 2021

Class plan

Algoritmos en Pseint

Un algoritmo se puede definir como una secuencia de instrucciones que representan un modelo de solución para determinado tipo de problemas. O bien como un conjunto de instrucciones que realizadas en orden conducen a obtener la solución de un problema.

Lenguaje de Programación:

Todos los lenguajes de programación comparten algunos elementos básicos que funcionan y se usan de forma diferente en cada lenguaje, pero que cumplen el mismo objetivo. Esos elementos son:

·         Tipos de datos

·         Variables

·         Control de flujo

·         Ciclos

·         Estructuras de datos

·         Funciones

Tipos de datos: Algunos lenguajes de programación tienen más tipos de datos que otros, pero, en general, todos incluyen al menos los siguientes: caracteres (char), cadenas de caracteres (string), enteros (integer), decimales (decimal, float), y booleanos (true y false).

Variables

Las variables nos permiten almacenar información temporalmente. Por ejemplo, podemos almacenar la cadena “Hola Mundo” en una variable.

GUIA 1. Calcular el doble de un número ingresado, a ese resultado calcularle el 10% y mostrar ese valor.

Recuerda ingresar a Pseint, en proceso escribes la referencia del algoritmo sin espacio

Proceso diezdoble
Escribir "Ingrese un numero";
Leer n
doble<-n*2;
por<-doble*.1;
Escribir "El 10% del doble de ",n," es ",por;
FinProceso

GUIA 2. Calcular el área de un rectángulo conociendo el valor de sus lados.

GUIA 3. Conociendo el valor de la entrada al cine, calcule el monto a pagar para una delegación de personas. Recuerde que deberá hacer un descuento del 3% por cantidad.

GUIA4. Hacer un algoritmo en Pseint que lea un número por el teclado y determinar si tiene tres dígitos.

Proceso NumeroTresDigitos
 Definir x Como Entero;
 Escribir "Ingrese un número";
 Leer x;
 
 si (x > 100 y x < 999) entonces
  Escribir "El número ",x," tiene tres dígitos";
 SiNo
  Escribir "El número ",x," no tiene tres dígitos";
 FinSi
 
FinProceso 

GUIA 5. Hacer un algoritmo en Pseint para una tienda de zapatos que tiene una promoción de descuento para vender al mayor, esta dependerá del número de zapatos que se compren. Si son más de diez, se les dará un 10% de descuento sobre el total de la compra; si el número de zapatos es mayor de veinte pero menor de treinta, se le otorga un 20% de descuento; y si son más treinta zapatos se otorgará un 40% de descuento. El precio de cada zapato es de $80.

Proceso TiendaZapato Definir xx,monto Como Entero; monto <- 0; Escribir 'Ingrese los datos de la compra'; Escribir "Zapatos comprados"; Leer xx; monto <- xx * 80; si (xx < 10) entonces Escribir "El monto total a pagar es: ", monto; SiNo si(xx < 20) entonces Escribir "El monto total a pagar es: ", monto - (monto * 0.1); // monto * .01 representa el descuento sino si(xx < 30) Entonces Escribir "El monto total a pagar es: ", monto - (monto * 0.2); // monto * .02 representa el descuento SiNo Escribir "El monto total a pagar es: ", monto - (monto * 0.4); // monto * .04 representa el descuento FinSi FinSi FinSi FinProceso

GUIA 6.Utiliza la fórmula resolvente para determinar las raíces de una ecuación de segundo grado a partir de sus tres coeficientes, y las informa adecuadamente según su tipo (reales iguales, reales distintas, imaginarias)

 // calcula las raices de una ecuacion de segundo grado

Proceso Resolvente
    
    // cargar datos
    Escribir "Ingrese el coeficiente A:"
    Leer a
    Escribir "Ingrese el coeficiente B:"
    Leer b
    Escribir "Ingrese el coeficiente C:"
    Leer c
    
    // determinar si son reales o imaginarias
    disc <- b^2-4*a*c
    Si disc<0 Entonces
        // si son imaginarias
        preal<- (-b)/(2*a)
        pimag<- rc(-disc)/(2*a)
        Escribir "Raiz 1: ",preal,"+",pimag,"i"
        Escribir "Raiz 2: ",preal,"-",pimag,"i"
    Sino
        Si disc=0 Entonces // ver si son iguales o distintas
            r <- (-b)/(2*a)
            Escribir "Raiz 1 = Raiz 2: ",r
        Sino
            r1 <- ((-b)+rc(disc))/(2*a)
            r2 <- ((-b)-rc(disc))/(2*a)
            Escribir "Raiz 1: ",r1
            Escribir "Raiz 2: ",r2
        FinSi
    FinSi
    
FinProceso

GUIA 7. Ejemplo de algoritmo para descomponer un número en sus factores primos.

Proceso Factorizacion
    
    Escribir "Ingrese el numero: "
    Leer num
    
    Escribir "Factorizacion: "
    
    factorizar<-verdadero
    
    Mientras factorizar Y num>1 hacer
        div<-0
        Si num/2 = trunc(num/2) Entonces
            Escribir 2
            num<-num/2
        Sino
            div<-1; factor_primo<-Verdadero
            Mientras div<=rc(num) Y factor_primo Hacer
                div <- div+2
                Si num/div = trunc(num/div) Entonces
                    factor_primo <- Falso
                FinSi
            FinMientras
            Si factor_primo Entonces
                escribir num
                factorizar<-falso
            sino
                escribir div
                num<-num/div
                factor_primo<-verdadero
            FinSi
        FinSi
    FinMientras
    
FinProceso
GUIA8. Este algoritmo determina a partir de las longitudes de tres lados de un triángulo si corresponden a un triángulo rectángulo (para utiliza la relación de Pitágoras, tomando los dos lados de menor longitud como catetos), y en caso afirmativo informa el área del mismo. Ejemplo de la estructura Si-Entonces y anidamiento.
//    Lee los tres lados de un triangulo rectangulo, determina 
// si corresponden (por Pitargoras) y en caso afirmativo 
// calcula el area

Proceso TrianguloRectangulo
    

    // cargar datos
    Escribir "Ingrese el lado 1:"
    Leer l1
    Escribir "Ingrese el lado 2:"
    Leer l2
    Escribir "Ingrese el lado 3:"
    Leer l3
    
    // encontrar la hipotenusa (mayor lado)
    Si l1>l2 Entonces
        cat1<-l2
        Si l1>l3 Entonces
            hip<-l1
            cat2<-l3
        Sino
            hip<-l3
            cat2<-l1
        FinSi
    Sino
        cat1<-l1
        Si l2>l3 Entonces
            hip<-l2
            cat2<-l3
        Sino
            hip<-l3
            cat2<-l2
        FinSi
    FinSi
    
    // ver si cumple con Pitagoras
    Si hip^2 = cat1^2 + cat2^2 Entonces
        // calcualar area
        area<-(cat1*cat2)/2
        Escribir "El area es: ",area
    Sino
        Escribir "No es un triangulo rectangulo."
    FinSi
    
FinProceso
FAVOR GUARDAR EN CARPETA Y ENVIAR POR PHIDIAS MENSAJES O CORREO INSTITUCIONAL.
VALIDO COMO NOTA 2DO PERIODO 2021.